贡献全自动学习练习打坐脚本,一键提升自己

墨匿

大概功能是,按照你指定的顺序依次学习/练习技能.
如果学习的时候师傅被杀了就会去练习.
都结束之后,会按照你的要求去做别的事儿.

这个主要是我鼓舞的时候用的.接一个鼓舞的触发器,然后鼓舞后自动去学习练习.欢迎提出建议

//一键学习
//@author 墨匿
// 全流程学习  学习 - 练习 - 打坐(挖矿)
@toolbar score
@js ($menpai)=$("[data-prop='family']").text()
@js ($shifu)=$("[data-prop='master']").text()
@js ($role_level)=$("[data-prop='level']").text()
//这里自己填写技能学习顺序
($xue_queue)=空
($lianxi_queue)=空
[if] (shifu) == 雾中楼
    ($xue_queue)=mantianhuayu,taxuexunmei
    ($lianxi_queue)=force,shashengjue
[if] (shifu) == 逍遥子
    ($xue_queue)=liuyangzhang,xiaowuxianggong,lingboweibu
    ($lianxi_queue)=blade,sword,beimingshengong,unarmed
[if] (shifu) == 灭绝
    ($xue_queue)=parry,jindingzhang,linjizhuang
    ($lianxi_queue)=club,juemengun
[if] (shifu) == 风清扬
    ($lianxi_queue)=sword,parry,dugujiujian,zixiashengong



[if] (afterLearn) == null
    ($afterLearn) = 帮派打坐
    [if] (menpai) == 逍遥派
        ($afterLearn)=挖矿
[if] (learnSet) == null
    ($learnSet) = 2
[if] (learnMax) == null
    [if] (role_level) == 武师
        ($learnMax) = 800
    [else]
        ($learnMax) = 1000 
#select ($afterLearn) = 学习练习结束之后干什么?,帮派打坐|挖矿,(afterLearn)
#select ($learnSet) = 学习套装,1|2|3,2
#input ($learnMax) = 练习到多少级?,(learnMax)
#input ($xue_queue) = 学习队列 逗号分隔,(xue_queue)
#input ($lianxi_queue) = 练习队列 逗号分隔,(lianxi_queue)

#config


<-stopSSAuto


[if] (shifu) == 谷虚道长||(shifu) == 宋远桥
    ($Location) = 武当派-三清殿
[if] (shifu) == 张三丰
    ($Location) = 武当派-后山小院
[if] (shifu) == 清乐比丘
    ($Location) = 少林派-广场
[if] (shifu) == 道绝禅师
    ($Location) = 少林派-天王殿
[if] (shifu) == 慧合尊者
    ($Location) = 少林派-般若堂
[if] (shifu) == 澄净
    ($Location) = 少林派-罗汉堂
[if] (shifu) == 玄难
    ($Location) = 少林派-方丈楼
[if] (shifu) == 高根明
    ($Location) = 华山派-镇岳宫
[if] (shifu) == 岳不群
    ($Location) = 华山派-客厅
[if] (shifu) == 封不平
    ($Location) = 华山派-林间小屋
[if] (shifu) == 风清扬
    ($Location) = 华山派-落雁峰
[if] (shifu) == 苏梦清
    ($Location) = 峨眉派-庙门
[if] (shifu) == 静心
    ($Location) = 峨眉派-大殿
[if] (shifu) == 周芷若
    ($Location) = 峨眉派-小屋
[if] (shifu) == 灭绝
    ($Location) = 峨眉派-清修洞
[if] (shifu) == 薛慕华
    ($Location) = 逍遥派-木屋
[if] (shifu) == 苏星河
    ($Location) = 逍遥派-青草坪
[if] (shifu) == 逍遥子
    ($Location) = 逍遥派-地下石室
[if] (shifu) == 左全
    ($Location) = 丐帮-树洞下
[if] (shifu) == 简长老
    ($Location) = 丐帮-土地庙
[if] (shifu) == 鲁有脚
    ($Location) = 丐帮-林间小屋
[if] (shifu) == 洪七公
    ($Location) = 丐帮-林间小屋
[if] (shifu) == 何小二
    ($Location) = 杀手楼-大厅
[if] (shifu) == 李四
    ($Location) = 杀手楼-银楼
[if] (shifu) == 雾中楼
    ($Location) = 杀手楼-书房
[if] (shifu) == 武馆教习
    ($Location) = 扬州城-扬州武馆



$wait 500

//先去学习
stopstate;$to (Location)
$eq (learnSet)
($needStudy) = false
($needPractice) = false

<---
[if] (needStudy) == true || (needPractice) == true
    [while] true
        [if] (needStudy) == true
            @print <hir>学习(current_skill)中.. 鼓舞(:status success)<hir>
        [else if] (needPractice) == true
            @print <hir>练习(current_skill)中.. 鼓舞(:status success)<hir>
        @print ->学习:(xue_queue)
        @print    ->练习:(lianxi_queue)
        @print      ->(afterLearn)

        [if] (needStudy) == true && {r(shifu)}? == null 
            @print <hir>退出!你的师傅不在了...</hir>
            ($needStudy)=false
            [break]

        [if] (arg0) == success && (:state success) == false 
            ($needStudy) = false
            ($needPractice) = false
            @print <hir>退出!鼓舞消失...</hir>
            $zdwk
            [break]
        [if] (:state) == 挖矿
            @print <hir>执行下一项!你跑去挖矿了</hir>
            stopstate;$to (Location)
            [break]
        [if] (:state) == 发呆
            $wait 500
            [if] (:state) == 发呆
                @print <hir>执行下一项!你在发呆...</hir>
                stopstate;$to (Location)  
                [break]     
        $wait 12130
--->
//解析学习队列并执行
[if] (xue_queue) != 空
    @js ($xue_length) = "(xue_queue)".split(",").length
    ($num)=0
    [while](num) < (xue_length)
       @js ($current_skill) = "(xue_queue)".split(",")[(num)]
       ($num) = (num) + 1
       @print <hir>当前学习:(current_skill)</hir>
       ($needStudy) = true
       xue (current_skill) from {r(shifu)}?
       ($needStudy) = false

($needStudy) = false
//学习完队列里所有的,进入练习流程
@print  <hir>学习完毕(或者全部失败),开始去练习</hir>

//解析练习队列并执行
[if] (lianxi_queue) != 空
    ($Location) = 帮会-练功房
    @js ($lianxi_length) = "(lianxi_queue)".split(",").length
    ($num)=0
    [while](num) < (lianxi_length)
       @js ($current_skill) = "(lianxi_queue)".split(",")[(num)]
       ($num) = (num) + 1
       @print <hir>当前练习:(current_skill)</hir>
       ($needPractice) = true
       lianxi (current_skill) (learnMax)
       ($needPractice) = false


//练习学习都结束 ,按照指定的执行下一个动作
($needStudy)=false
($needPractice) = false
@print  <hir>学习练习完毕(或者全部失败),开始去(afterLearn)</hir>

[if] (afterLearn) == 帮派打坐
    $to 帮会-练功房
    $wait 300
    dazuo
[else if] (afterLearn) == 挖矿
    $zdwk

stopSSAuto->

复制上方代码

sbndjgg

感谢大佬分享，试一下效果。

Secave

@墨匿 dalao，关于散人玩法，师门师傅那一栏显示的是无门无派和无，执行不了学习流程

贡献 全自动学习练习打坐脚本,一键提升自己

贡献全自动学习练习打坐脚本,一键提升自己