请问代码太长了换行怎么操作


  • 宗师

    代码太长了,系统直接换行,但是会运行错误流程直接退出,之前记得你说过加/t,但是没什么用,尤其是[if] 2层嵌套



  • @老实人 发出来看看


  • 宗师

    jh fam 5 start
    task sm {r苏星河}
    @tip 苏星河对你说道:我要的是($prop),你要是找不到就换别的吧。
    pack none
    ($num)=false
    [if] {b(prop)}? == null
      [if] (prop)==<wht>布衣</wht>||(prop)==<wht>钢刀</wht>||(prop)==<wht>木棍</wht>||(prop)==<wht>英雄巾</wht>||(prop)==<wht>布鞋</wht>||(prop)==<wht>铁戒指</wht>||(prop)==<wht>簪子</wht>||(prop)==<wht>长鞭</wht>||(prop)==<wht>钓鱼竿</wht>||(prop)==<wht>鱼饵</wht>
        @call 杂货铺 (prop)
        ($num)=true
      [if] (num)==false
        @call 仓库 (prop)
    [if] {b(prop)}? != null
      task sm {r苏星河}
      task sm {r苏星河} give {b(prop)}
    
    复制上方代码

    像这样,发论坛上面看不出



  • @老实人 这个代码就这样拷贝进去,会在哪里出错



  • @老实人 你说的系统直接换行,那个没关系,那只是显示问题,实际上还是一行


  • 宗师

    是我强迫症犯了,我看他换行换的不对称,然后手动换行,然后就运行不了,直接复制进去是没问题的



  • @老实人 好的 🤣


  • 宗师

    @Bob-cn

    jh fam 0 start
    go east[2];go south
    list {r铁匠铺老板 铁匠ָ%}
    @dialog
    buy 1 {d铁棍} from {r铁匠铺老板 铁匠ָ%}
    
    复制上方代码

    请问大佬这代码有哪里有问题吗?

    执行系统命令: jh fam 0 start
      执行系统命令: go east;go east;go south
      等待,直至符合条件: @until {r铁匠铺老板 铁匠ָ%}? != null
    
    复制上方代码

    卡住了?
    尝试过很多名字(铁匠铺老板、铁匠ָ)都不行。



  • @老实人请问代码太长了换行怎么操作 中说:

    list {r铁匠铺老板 铁匠ָ%}

    list {r铁匠铺老板 铁匠%}

    拷贝我上面打的


  • 宗师

    有什么不同,看不出,但是我用VScode的确是不同



  • @老实人 多了一个字符 ָ

    list {r铁匠铺老板 铁匠ָ%}

    list {r铁匠铺老板 铁匠%}


  • 宗师

    @Bob-cn

    #input ($repeat) = 重复次数,1
    #config
    ($num_1) = 0
    [while] (num_1) < (repeat)
        jh fam 5 start
        task sm {r苏星河}
        task sm {r苏星河}
        @tip 苏星河对你说道:我要的是($prop),你要是找不到就换别的吧。
        pack none
        ($num)=false
        [if] {b(prop)}? == null
        [if] (prop)==<wht>布衣</wht>||(prop)==<wht>钢刀</wht>||(prop)==<wht>木棍</wht>||(prop)==<wht>英雄巾</wht>||(prop)==<wht>布鞋</wht>||(prop)==<wht>铁戒指</wht>|| (prop)==<wht>簪子</wht>||(prop)==<wht>长鞭</wht>||(prop)==<wht>钓鱼竿</wht>||(prop)==<wht>鱼饵</wht>
            jh fam 0 start
            go east;go south
            list {r杨永福}
            @dialog
            buy 1 {d(prop)} from {r杨永福}
            ($num)=true
        [if] (prop)==<hig>金创药</hig>||(prop)==<hig>引气丹</hig>||(prop)==<hig>养精丹</hig>
            jh fam 0 start
            go east[2];go north
            list {r药铺老板 平一指%}
            @dialog
            buy 1 {d(prop)} from {r药铺老板 平一指%}
            ($num)=true
        [if] (prop)==<wht>铁剑</wht>||(prop)==<wht>钢刀</wht>||(prop)==<wht>铁棍</wht>||(prop)==<wht>铁杖</wht>||(prop)==<wht>飞镖</wht>
            jh fam 0 start
            go east[2];go south
            list {r铁匠铺老板 铁匠%}
            @dialog
            buy 1 {d(prop)} from {r铁匠铺老板 铁匠%} 
            ($num)=true
        [if] (prop)==<wht>米饭</wht>||(prop)==<wht>包子</wht>||(prop)==<wht>鸡腿</wht>||(prop)==<wht>面条</wht>||(prop)==<wht>扬州炒饭</wht>||(prop)==<wht>米酒</wht>||(prop)==<wht>花雕酒</wht>||(prop)==<wht>女儿红</wht>||(prop)==<hig>醉仙酿 </hig>||(prop)==<hiy>神仙醉</hiy>
            jh fam 0 start
            go north[2];go east
            list {r店小二}
            @dialog
            buy 1 {d(prop)} from {r店小二}
            ($num)=true
        [if] (num)==false
            jh fam 0 start
            go west[2];go north;go enter
            go north
            store
            @dialog
            ($got) = false
            [if] {d(prop)}? != null
                qu 1 {d(prop)}
                ($got) = true
            [if] (got) == false
                go south;go northeast
                dc {r小流氓} stopstate
                pack {r小流氓}
                @dialog
                [if] {d(prop)}? != null
                    dc {r小流氓} give {r云曹} 1 {d(prop)}
                    ($got) = true
                dc {r小流氓} diao
            [if] (got) == false
                dc {r丫鬟} stopstate
                pack {r丫鬟}
                @dialog
                [if] {d(prop)}? != null
                    dc {r丫鬟} give {r云曹} 1 {d(prop)}
                    ($got) = true
                dc {r丫鬟} cai
        [if] {b(prop)}? != null
            jh fam 5 start
            task sm {r苏星河}
            task sm {r苏星河} give {b(prop)}
        ($num_1) = (num_1) + 1
    $zdwk
    
    复制上方代码

    自动师门任务,可以自动从仓库或者随从拿东西,但是有个问题,有时候从仓库里拿出东西会交不了,似乎是ID变了,但是刷新一下又可以了,求大佬看看。



  • @老实人 好像是有点问题,我看一下



  • @老实人 v2.1.22 2019-02-27 - 修复了从仓库拿取物品后的物品id异常 😅


  • 宗师

    @Bob-cn
    大佬厉害,大佬威武👍 👍 👍



  • @老实人 😅谢谢


  • 宗师

    @Bob-cn
    大佬收徒儿不



  • @老实人 有啥问题问就好啦,论坛还没开发师徒系统😁


  • 宗师

    @老实人请问代码太长了换行怎么操作 中说:

    自动师门任务

    [if] ($Boss) == null
        ($Boss) = 默认值
    [if] ($Gather) == null
        ($Gather) = 默认值
    [if] ($Fish) == null
        ($Fish) = 默认值
    [if] ($Give_up) == null
        ($Give_up) = 默认值
    #select ($Boss) = 门派任务,宋远桥|清乐比丘|高根明|苏梦清|苏星河|左全,(Boss)
    #select ($Gather) = 采集随从,丫鬟|小流氓|程灵素|黄蓉|小昭|韦春芳|无,(Gather)
    #select ($Fish) = 钓鱼随从,丫鬟|小流氓|程灵素|黄蓉|小昭|韦春芳|无,(Fish)
    #select ($Give_up) = 自动放弃,是|不,(Give_up)
    #config
    stopstate
    [while] true
        ($iden) = false
        ($hard) = null
        [if] (Boss) == 宋远桥
            jh fam 1 start;go north
        [if] (Boss) == 苏梦清
            jh fam 4 start;go west
        [if] (Boss) == 左全
            jh fam 6 start;go down
        [if] (Boss) == 清乐比丘
            jh fam 2 start
        [if] (Boss) == 高根明
            jh fam 3 start    
        [if] (Boss) == 苏星河 
            jh fam 5 start
        task sm {r(Boss)}
        task sm {r(Boss)}
        @tip (Boss)对你说道:我要的是($prop),你要是找不到就换别的吧。|(Boss)对你点头道:($hard), 你先去休息一下吧。
        pack none
        ($num)=false
        [if] (hard) == 辛苦了
            $zdwk
            @exit
        [if] {b(prop)}? == null
            [if] (prop)==<wht>布衣</wht>||(prop)==<wht>钢刀</wht>||(prop)==<wht>木棍</wht>||(prop)==<wht>英雄巾</wht>||(prop)==<wht>布鞋</wht>||(prop)==<wht>铁戒指</wht>|| (prop)==<wht>簪子</wht>||(prop)==<wht>长鞭</wht>||(prop)==<wht>钓鱼竿</wht>||(prop)==<wht>鱼饵</wht>
                jh fam 0 start;go east;go south
                list {r杨永福}
                @dialog
                buy 1 {d(prop)} from {r杨永福}
                ($num)=true
            [if] (prop)==<hig>金创药</hig>||(prop)==<hig>引气丹</hig>||(prop)==<hig>养精丹</hig>
                jh fam 0 start;go east[2];go north
                list {r药铺老板 平一指%}
                @dialog
                buy 1 {d(prop)} from {r药铺老板 平一指%}
                ($num)=true
            [if] (prop)==<wht>铁剑</wht>||(prop)==<wht>钢刀</wht>||(prop)==<wht>铁棍</wht>||(prop)==<wht>铁杖</wht>||(prop)==<wht>飞镖</wht>
                jh fam 0 start;go east[2];go south
                list {r铁匠铺老板 铁匠%}
                @dialog
                buy 1 {d(prop)} from {r铁匠铺老板 铁匠%} 
                ($num)=true
            [if] (prop)==<wht>米饭</wht>||(prop)==<wht>包子</wht>||(prop)==<wht>鸡腿</wht>||(prop)==<wht>面条</wht>||(prop)==<wht>扬州炒饭</wht>||(prop)==<wht>米酒</wht>||(prop)==<wht>花雕酒</wht>||(prop)==<wht>女儿红</wht>||(prop)==<hig>醉仙酿</hig>||(prop)==<hiy>神仙醉</hiy>
                jh fam 0 start;go north[2];go east
                list {r店小二}
                @dialog
                buy 1 {d(prop)} from {r店小二}
                ($num)=true
            [if] (num)==false
                jh fam 0 start;go west[2];go north;go enter;go north
                store
                @dialog
                ($got) = false
                [if] {d(prop)}? != null
                    qu 1 {d(prop)}
                    ($got) = true
                [if] (got) == false
                    go south;go northeast
                    [if] (Gather) != 无
                        dc {r(Gather)} stopstate
                        pack {r(Gather)}
                        @dialog
                        [if] {d(prop)}? != null
                            dc {r(Gather)} give (:id) 1 {d(prop)}
                            ($got) = true
                        dc {r(Gather)} cai
                    [if] (got) == false
                        [if] (Fish) != 无
                            dc {r(Fish)} stopstate
                            pack {r(Fish)}
                            @dialog
                            [if] {d(prop)}? != null
                                dc {r(Fish)} give (:id) 1 {d(prop)}
                                ($got) = true
                            dc {r(Fish)} diao
        [if] (Boss) == 宋远桥
            jh fam 1 start;go north
        [if] (Boss) == 苏梦清
            jh fam 4 start;go west
        [if] (Boss) == 左全
            jh fam 6 start;go down
        [if] (Boss) == 清乐比丘
            jh fam 2 start
        [if] (Boss) == 高根明
            jh fam 3 start    
        [if] (Boss) == 苏星河 
            jh fam 5 start
        [if] {b(prop)}? != null    
            task sm {r(Boss)}
            task sm {r(Boss)} give {b(prop)}
            ($iden)=true
        [if] {b(prop)}? == null && (Give_up) == 是 && (iden) == false
            task sm {r(Boss)}
            task sm {r(Boss)} giveup 
    $zdwk
    
    复制上方代码

登录后回复